「tcsh」の設定

トップ

Solaris

FreeBSD

Gentoo

こちらは特にOSに依存しない一般的な「tcsh」の設定方法だが、 Solarisに特化した設定ファイルのサンプルはこちら。

「tcsh」の設定

Unix$ vi ~/.tcshrc <= 設定ファイルの編集
# エイリアス
alias h      'history 32'
alias ll     'ls -laF | more'

# TAB補完でもカラー表示
set color
# ファイル名の補完で複数の候補が有る場合、一覧を表示する
set autolist
# 「Esc」キーでファイル名の補完を行う
set filec
# [Ctrl] + [D]でログアウトしない
set ignoreeof
# ヒストリに保存するコマンド
set history = 10000
# 「~/.history」に保存するコマンド(マージする)
set savehist = (10000 merge)
# 入力行と一致するヒストリは削除
set histdup = erase
# ヒストリにサーチ機能を付加
bindkey -k up history-search-backward
bindkey -k down history-search-forward

# cdコマンドの補完ではディレクトリのみを対象にする
complete cd  'p/1/d/'

# タイトルバーの設定
if( $?TERM )then
    switch( $TERM )
    case xterm:
    case kterm:
    case dtterm:
        alias precmd 'printf "\033]2;${HOST}\007"' # \033]2; と \007 の間の部分がタイトルバーに表示される
    endsw
endif

# プロンプトの設定
# %n : ユーザ名
# %m : マシン名
# %c : カレントディレクトリ
# %# : スーパーユーザは「#」一般ユーザは「>」で表示
set prompt='%{\033[36m%n@%m %c%#\033[00m%} '


Unix$ source ~/.tcshrc <= .tcshrcファイルの読み込み

書式の指定

プロンプトの設定でカラー表示しているが、色の指定は
set prompt='%{\033[36m%n@%m %c%#\033[00m%} '
の 36 の部分で行う。
書式の指定方法は以下の通り。

書式	番号
通常	00
太字	01
下線	04
点滅	05
前背色反転	07
表示しない	08
ノーマル化	22
下線なし	24
点滅なし	25
前背色反転なし	27

色	番号（文字）	番号（背景）
黒	30	40
赤	31	41
緑	32	42
黄	33	43
青	34	44
紫	35	45
シアン	36	46
灰	37	47
デフォルト	39	49

複数指定する場合、以下のようにセミコロンで区切る。

set prompt='%{\033[01;36;45m%n@%m %c%#\033[00m%} '

▲ページのトップへ