Solaris% vi ~/.cshrc <= 設定ファイルの作成
# パスの設定
set path=(/usr/bin /usr/dt/bin /usr/openwin/bin /bin /usr/ucb /usr/sfw/bin /opt/sfw/bin /usr/ccs/bin /usr/local/bin)

# エイリアス
alias ll     'ls -laF | more'
alias h      'history 32'
# CompanionCDをインストールしている場合、以下の設定も行う
alias ls     'gls -F --color=always'
alias make   'gmake'
alias ar     'gar'
alias tar    'gtar'

# TAB補完でもカラー表示
set color
# 「Esc」キーでファイル名の補完を行う
set filec
# ヒストリに保存するコマンド
set history = 10000
# 「~/.history」に保存するコマンド(マージする)
set savehist = (10000 merge)
# [Ctrl] + [D]でログアウトしない
set ignoreeof
# ファイル名の補完で複数の候補が有る場合、一覧を表示する
set autolist
# プロンプトの設定
# `/usr/ucb/whoami`   : ユーザ名
# `/usr/bin/uname -n` : マシン名
set prompt="`/usr/ucb/whoami`@`/usr/bin/uname -n`% "

# lsの結果をlessに渡してもカラー表示にする
setenv LESS -r

# エディタの設定
setenv EDITOR  vi

# manのパスの設定
setenv MANPATH /usr/man:/usr/share/man:/usr/openwin/share/man:/usr/sfw/man
setenv MANPATH "$MANPATH":/usr/local/man:/usr/local/share/man

# tcshの場合
if ( ${?tcsh} ) then
    # タイトルバーの変更
    if( $?TERM )then
        switch( $TERM )
        case xterm:
        case kterm:
        case dtterm:
            alias precmd 'printf "\033]2;${HOST}\007"' # \033]2; と \007 の間の部分がタイトルバーに表示される
        endsw
    endif
    # プロンプトの設定
    # %n : ユーザ名
    # %m : マシン名
    # %c : カレントディレクトリ
    # %# : スーパーユーザは「#」一般ユーザは「>」で表示
    set prompt='%{\033[1;36m%n@%m %c%#\033[00m%} '

    # cdコマンドの補完ではディレクトリのみを対象にする
    complete cd  'p/1/d/'
    # 入力行と一致するヒストリは削除
    set histdup = erase
    # ヒストリにサーチ機能を付加
    bindkey -k up history-search-backward
    bindkey -k down history-search-forward
endif


Solaris% source ~/.cshrc <= .cshrcファイルの読み込み

set prompt='%{\033[01;36;45m%n@%m %c%#\033[00m%} '